[demolux]

Moin,
so eine Ansteuerung per "Dauerkontakt" wäre für mich schon besser, da ich angedacht hatte, einen zweipoligen Kippschalter zu verwenden, um gleichzeitig noch den Fahrstrom im Schuppen bei geschlossenem Tor abzuschalten. (muss ja nicht unnötig mit Strom versorgt werden).

Allerdings kann ich auch schlecht einschätzen, wie viel Arbeit das bereitet, dieses Verhalten nachträglich noch einzubauen und ob es außer mir noch jemand anderes benötigen würde...

[MicroBahner]

Ich habe ja geschrieben, dass es eigentlich gehen müsste. Nur der EEPROM.write Befehel macht Probleme. Aber in dem von Werner verlinkten Thread habe ich ja schon geschrieben, wie man das lösen kann. Du musst nur das EEPROM.write durch ein EEPROM.update austauschen.
Probier's halt einfach aus .
Was allerdings nicht funktioniert, ist das automatische Abschalten der Impulse, da das Servo.write ständig aufgerufen wird. Da müsste man dann noch ein Flag einführen, ob das Tor gerade zugemacht oder aufgemacht wurde.

[md95129]

Warum nicht einen "DPDT Miniature Toggle Switch MOM-OFF-MOM" https://www.jameco.com/z/1MD4T6B11M1QE-D...-5A_317498.html oder einen DPDT MOM-OFF verwenden? Strom brauchst Du ja nur waehrend der Ein/Ausfahrt der Lok.

[fischi01]

Hallo!
Ich habs wohl immer noch nicht richtig verstanden.
Probiere einen 5fach Servodecoder zu programmieren, bekomme aber folgende Fehlermeldung.

Arduino: 1.8.12 (Windows 8.1), Board: "Arduino Nano, ATmega328P (Old Bootloader)"

In file included from C:UsersRenéDownloadsDCC_Zubehoerdecoder-6.2.0DCC_Zubehoerdecoder1DCC_Zubehoerdecoder1.ino:26:0:

Interface.h:11:10: fatal error: src/DebugDefs.h: No such file or directory

#include "src/DebugDefs.h"

^~~~~~~~~~~~~~~~~

compilation terminated.

exit status 1
src/DebugDefs.h: No such file or directory

Dieser Bericht wäre detaillierter, wenn die Option
"Ausführliche Ausgabe während der Kompilierung"
in Datei -> Voreinstellungen aktiviert wäre.

Was mache ich falsch?
Bin auf diesem Gebiet leider Anfänger.

Gruß und danke RENÈ

[MicroBahner]

Hallo RENÈ

Zitat

---

DCC_Zubehoerdecoder1DCC_Zubehoerdecoder1.ino:26:0:

---

Du hast offensichtlich ein neues Verzeichnis mit dem .ino-File angelegt ( im zip-File heißt das Verzeichnis ja DCC_Zubehoerdecoder - ohne die 1 ). Hast Du da auch alles aus dem Original-Verzeichnis reinkopiert? Es scheint so, dass das 'src' Unterverzeichnis fehlt.

[fischi01]

Hallo Franz-Peter!

Die Datei hat wirklich gefehlt!. Währe mir nie aufgefallen. Danke.
Allerdings hab ich eine neue Fehlermeldung bei den Pins.

Arduino: 1.8.12 (Windows 8.1), Board: "Arduino Nano, ATmega328P (Old Bootloader)"

In file included from C:UsersRenéDownloadsDCC_Zubehoerdecoder-6.2.0DCC_Zubehoerdecoder1DCC_Zubehoerdecoder1.ino:72:0:

DCC_Zubehoerdecoder.h:163:1: error: expected primary-expression before 'const'

const byte out1Pins[] = { A0, A1, A6, A7, 3,

^~~~~

DCC_Zubehoerdecoder.h:163:1: error: expected '}' before 'const'

exit status 1
expected primary-expression before 'const'

Dieser Bericht wäre detaillierter, wenn die Option
"Ausführliche Ausgabe während der Kompilierung"
in Datei -> Voreinstellungen aktiviert wäre.
Habe ich dort ein Pin genommen was nicht geeignet ist?
Danke und Gruß RENÈ

[Bodo]

Hallo René,

laut Fehlermeldung fehlt eine Klammer am Ende - aber A6 und A7 sind auch keine Ausgänge, sondern beim Nano nur Eingänge.

Viele Grüße, Bodo

[fischi01]

Hallo Bodo!

Das wars!!!! Hochladen abgeschlossen.
Danke und schönen Abend RENÈ.
War aber bestimmt nicht die letzte Frage.

Gruß RENÈ

[MicroBahner]

Zitat

---

aber A6 und A7 sind auch keine Ausgänge, sondern beim Nano nur Eingänge.

---

Und zwar ausschließlich analoge Eingänge. Die kann man weder als digitalen Eingang, noch als digitalen Ausgang nutzen.

[Babbel]

Hallo Franz-Peter,

beim Kompilieren des Beispiels "Stepper_01" bekomme ich in der Arduino IDE die Meldung:
"no matching function for call to 'MoToStepper::MoToStepper(int, int)" .

Was für eine Fehler mache ich ?

Grüße und vielen dank für die Arbeit welche du dir machst.

Berthold

[MicroBahner]

Hallo Berthold,
vermutlich willst Du das Beispiel für einen ESP8266 kompilieren? Für den ESP8266 kennen die MobaTools die Stepperansteuerung nur über eine Step/Dir Anschluß. Der direkte Anschluß eines unipolaren Steppers mit 4 Anschlussen ist da nicht möglich. Deshalb gibt es auch den Konstruktor mit der entsprechenden Auswahl nicht. Um einen unipolaren Schrittmotor zu betreiben brauchst Du da einen entsprechenden Baustein, der das umsetzt wie z.B. den L297.

Aber deine Frage hat mir jetzt bewusst gemacht, dass es gar kein Beispiel für einen über Step/Dir angeschlossenen Schrittmotor gibt. Das habe ich mal auf meine ToDo Liste geschrieben. Ausserdem werde ich in das Beispiel noch einen entsprechenden Hinweis aufnehmen.

[fischi01]

Hallo Franz-Peter!

Habe erstmal einen einfachen DCC Decoder gebaut.
Ist es bei dem Sketch möglich die Adressen nach Roco in die normale Zählweise zu ändern?
Finde ich für mich übersichtlicher.
Noch eine Frage, kann ein Decoder 2mal die gleiche Adresse haben?
Ich möchte bei einigen Weichen die Laternen mit extra Servos machen.

Gruß und Danke RENÈ

[MicroBahner]

Hallo RENÈ,
Ohne deinen Decoder zu kennen, sind die Fragen nicht zu beantworten.
Und was meinst Du mit Rocoe-Zählweise? Nur den Versatz von 4?

[Charly2011]

Moin
ich hab das so gelöst.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 

const byte isROCO = 0  ;    // wegen unterschiedlicher Weichenadressberechnung bei Roco (sonst = 0)
 
//////////////////////////////////////////////////////////////
// Unterprogramme, die von der DCC Library aufgerufen werden:
// Die folgende Funktion wird von Dcc.process() aufgerufen, wenn ein Weichentelegramm empfangen wurde
void notifyDccAccState( uint16_t Addr, uint16_t BoardAddr, uint8_t OutputAddr, uint8_t State ){
    // Weichenadresse berechnen
    word wAddr = Addr+isROCO; // Roco zählt ab 0, alle anderen lassen die ersten 4 Weichenadressen frei
    // Testen ob eigene Weichenadresse
    for ( byte i = 0; i < ServoZahl; i++ ) {
        if (  wAddr ==( dccAdr+ weichenAdr[i] )) {
            // ist eigene Adresse, Servo ansteuern
            if ( OutputAddr & 0x1 ) {
                weicheS[i].write( geradePulse[i] );
            } else {
                weicheS[i].write( abzweigPulse[i] );
            }
            break; // Schleifendurchlauf abbrechen, es kann nur eine Weiche sein
        }
    }
}
 
 

lg Charly

[fischi01]

Danke!

Es geht um den Decoder.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 

#include <NmraDcc.h>
#include <MobaTools.h>
 
// Demo: ein ganz einfacher Dcc-Servodecoder //
//------------------------------------------ //
// die NmraDcc - Library gibt es unter https://github.com/mrrwa/NmraDcc/archive/master.zip
 
// anzupassende Konstante:
const byte isROCO = 4  ;    // wegen unterschiedlicher Weichenadressberechnung bei Roco (sonst = 0)
const byte weichenAdr[] =   { 253, 252, 251, 250, 249, 248, 251, 248};  // DCC-Weichenadressen 
const byte servoPins[]  =   {   3,   4,   5,   6,   7,   8,   9,  10};  // output-pin der Servos
const int geradePulse[] =   {1300,1200,1200,1200,1200,1200,1200,1200};  // Pulslänge geradeaus
const int abzweigPulse[]=   {1600,1800,1800,1800,1800,1800,1800,1800};  // Pulslänge abzweigend
 
const int speed = 8;
const byte autoOff = 1;
const byte ServoZahl = sizeof(weichenAdr);
Servo8 weicheS[ServoZahl];
NmraDcc Dcc;
///////////////////////////////////////////////////////////////
void setup() {
    Dcc.init( MAN_ID_DIY, 15, FLAGS_OUTPUT_ADDRESS_MODE | FLAGS_DCC_ACCESSORY_DECODER, 0 );
    Dcc.pin(0, 2, 1); // Dcc-Signal an Pin2 ( = Int0 );
 
    for ( byte i=0; i<ServoZahl; i++ ) {
        // Weichenservos initiieren
        weicheS[i].attach( servoPins[i], autoOff );
        weicheS[i].setSpeed( speed );
    }
}
////////////////////////////////////////////////////////////////
void loop() {
    Dcc.process(); // Hier werden die empfangenen Telegramme analysiert
    
}
//////////////////////////////////////////////////////////////
// Unterprogramme, die von der DCC Library aufgerufen werden:
// Die folgende Funktion wird von Dcc.process() aufgerufen, wenn ein Weichentelegramm empfangen wurde
void notifyDccAccState( uint16_t Addr, uint16_t BoardAddr, uint8_t OutputAddr, uint8_t State ){
    // Weichenadresse berechnen
    word wAddr = Addr+isROCO; // Roco zählt ab 0, alle anderen lassen die ersten 4 Weichenadressen frei
    // Testen ob eigene Weichenadresse
    for ( byte i = 0; i < ServoZahl; i++ ) {
        if (  wAddr == weichenAdr[i] ) {
            // ist eigene Adresse, Servo ansteuern
            if ( OutputAddr & 0x1 ) {
                weicheS[i].write( geradePulse[i] );
            } else {
                weicheS[i].write( abzweigPulse[i] );
            }
            break; // Schleifendurchlauf abbrechen, es kann nur eine Weiche sein
        }
    }
}
 
 

Leider weis ich nicht wie man das hier richtig einstellt!

Charlie das probiere ich aus.

Franz-Peter
Wenn dasmit den doppelten Adressen nicht so einfach geht kann ich immer noch 2 Decoder nehmen.
Aber heute ist mir noch was anderes aufgefallen.
Beim ersten mal schalten nach dem anschalten rennt der Servo in die Stellung, dann funktioniert alles ganz normal.
Umgehen kann ich das wenn ich die Stellung schalte wo er steht.

Gruß RENÈ.

[MicroBahner]

Hallo RENÈ,
das mit den doppelten Adressen sollte bei dem einfachen Decoder funktionieren, wenn Du diese Zeile:

1
 

            break; // Schleifendurchlauf abbrechen, es kann nur eine Weiche sein
 

löscht.

Das mit dem Roco-Offset sollte durch diese Zeile:

1
 

const byte isROCO = 4  ;    // wegen unterschiedlicher Weichenadressberechnung bei Roco (sonst = 0)
 

eigentlich schon drin sein.

Die schnelle Bewegung des Servo beim ersten Mal ist prinzipbedingt. Die langsame Bewegung kann man bei einem Servo nur erreichen, indem man ihm mit entsprechendem zeitlichen Abstand immer wieder neue Zwischenpositionen vorgibt. Das bedingt aber, dass das Programm beim Start der Bewegung weis, wo das Servo steht, damit es diese Zwischenpositionen berechnen kann. Das ist aber direkt nach dem Einschalten nicht der Fall. Deshalb wird bei der ersten Bewegung einfach die Zielposition angegeben, und das Servo bewegt sich dann mit seiner Eigengeschwindigkeit dorthin - es sei denn es steht schon da. Dann bleibt es natürlich einfach stehen, und man merkt von diesem Problem nichts. Ab der nächsten Bewegung kennt das Programm dann die Ausgangsposition und kann die Zwischenwerte berechnen.

[fischi01]

Hallo!

Es ist geschafft der Decoder funktioniert jetzt wie ich es brauche.
Danke an die Helfer.
Das mit der ersten schnellen Bewegung versuche ich dann mit Windigipet zu lösen.
Bin aber nicht sicher ob das klappt.
Oder hat noch jemand eine Idee?

Gruß RENÈ.

[MicroBahner]

Hallo RENÈ

Zitat

---

Oder hat noch jemand eine Idee?

---

Die schnelle Bewegung kannst Du verhindern, wenn Du dir bei jeder Umstellung eines Servo die aktuelle Position in EEPROM merkst. Im setup() werden dann erstmal alle Servos auf diese Position gestellt. Da sie ja schon da stehen, gibt es auch keine schnelle Bewegung.

[fischi01]

Hallo Franz-Peter

Dafür müßte ich programmieren können.
Habs versucht, es steht ja überall ist ganz einfach.
Aber ich komme da nicht mit zurecht.
Bin wohl ein hoffnungslosser Fall.
Aber ich würde mich freuen wenn mir jemand weiter hilft.

Gruß RENÈ

[MicroBahner]

Na ja, dazu ist bei diesem einfacheh Sketch ja nicht viel zu tun :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
 

#include <NmraDcc.h>
#include <MobaTools.h>
#include <EEPROM.h>
 
// Demo: ein ganz einfacher Dcc-Servodecoder //
//------------------------------------------ //
// die NmraDcc - Library gibt es unter https://github.com/mrrwa/NmraDcc/archive/master.zip
 
// anzupassende Konstante:
const byte isROCO = 4  ;    // wegen unterschiedlicher Weichenadressberechnung bei Roco (sonst = 0)
const byte weichenAdr[] =   { 253, 252, 251, 250, 249, 248, 251, 248};  // DCC-Weichenadressen 
const byte servoPins[]  =   {  3,  4,   5,   6,   7,   8,   9,  10};  // output-pin der Servos
const int geradePulse[] =   {1300,1200,1200,1200,1200,1200,1200,1200};  // Pulslänge geradeaus
const int abzweigPulse[]=   {1600,1800,1800,1800,1800,1800,1800,1800};  // Pulslänge abzweigend
 
const int speed = 8;
const byte autoOff = 1;
const byte ServoZahl = sizeof(weichenAdr);
Servo8 weicheS[ServoZahl];
NmraDcc Dcc;
///////////////////////////////////////////////////////////////
void setup() {
    Dcc.pin(digitalPinToInterrupt(2), 2, 1); // Dcc-Signal an Pin2 ( = Int0 );
    Dcc.init( MAN_ID_DIY, 15, FLAGS_OUTPUT_ADDRESS_MODE | FLAGS_DCC_ACCESSORY_DECODER, 0 );
 
    for ( byte i=0; i<ServoZahl; i++ ) {
        int inipos;
        // Weichenservos initiieren
        weicheS[i].attach( servoPins[i], autoOff );
        weicheS[i].setSpeed( speed );
        EEPROM.get(i*2, inipos );                   // letzten gespeicherten Wert aus dem EEPROM lesen
        inipos = constrain( inipos, 600, 2500 );    // auf gültige Werte begrenzen
        weicheS[i].write( inipos );                 // Servo dorthin fahren ( sollte bereits da stehen )
    }
}
////////////////////////////////////////////////////////////////
void loop() {
    Dcc.process(); // Hier werden die empfangenen Telegramme analysiert
    
}
//////////////////////////////////////////////////////////////
// Unterprogramme, die von der DCC Library aufgerufen werden:
// Die folgende Funktion wird von Dcc.process() aufgerufen, wenn ein Weichentelegramm empfangen wurde
//void notifyDccAccState( uint16_t Addr, uint16_t BoardAddr, uint8_t OutputAddr, uint8_t State ){
void notifyDccAccTurnoutOutput( uint16_t Addr, uint8_t OutputAddr, uint8_t OutputPower ) {
    // Weichenadresse berechnen
    word wAddr = Addr+isROCO; // Roco zählt ab 0, alle anderen lassen die ersten 4 Weichenadressen frei
    // Testen ob eigene Weichenadresse
    for ( byte i = 0; i < ServoZahl; i++ ) {
        if (  wAddr == weichenAdr[i] ) {
            // ist eigene Adresse, Servo ansteuern
            if ( OutputAddr & 0x1 ) {
                weicheS[i].write( geradePulse[i] );
                EEPROM.put(i*2,geradePulse[i]);
            } else {
                weicheS[i].write( abzweigPulse[i] );
                EEPROM.put(i*2,abzweigPulse[i]);
            }
            //break; // Schleifendurchlauf abbrechen, es kann nur eine Weiche sein
        }
    }
}
 

( Ich hab' den Sketch auch gleich an die aktuelle Version der NmraDcc Lib angepasst )

[fischi01]

Hallo Franz-Peter!

Ganz viel Dank!!!!
Zu dem Eprom, gibt es da eine Begrenzung der Anzahl der Ladezyklen.
Irgenwas hab ich da mal gelesen glaube ich jedenfalls.
Ich probiere morgen mal alles aus und melde mich nochmal.

Gruß RENÈ.

[MicroBahner]

Hallo RENÈ,

Zitat

---

Zu dem Eprom, gibt es da eine Begrenzung der Anzahl der Ladezyklen.

---

Ja, die Schreibzyklen sind begrenzt. Der Hersteller garantiert mindestens 100000 Schreibvorgänge. Die Frage ist, ob deine Weiche soviele Stellvorgänge aushält . Das EEPROM wird bei der verwendeten Funktion auch nur beschrieben, wenn sich der Inhalt tatsächlich geändert hat. Lesen kann man den Inhalt beliebig oft.

[Charly2011]

Klasse Projekt das MobaTool

Hat schon jemand eine Version der NMRADCC Library größer 1.2.1 an laufen gebracht ?
Sobald ich eine höhere Version nutze werden keinerlei DCC signale mehr eingelesen.
lg Charly

[Bodo]

Hallo Charly,

ich habe die Arduino-IDE 1.8.12 mit NmraDcc-Library 2.0.0 und MoBaTools 2.2.0 installiert und zumindest keine offensichtlichen Probleme.

Viele Grüße, Bodo

[fischi01]

Hallo!

Habe heute noch mal probiert, alles o.k.
Danke auch für die Eprom Erklärung.
Ich baue meine Leiterplatte fast immer auf Streifenrasterleiterplatten.
Hab ein Bild von dem Probierteil gemacht.



Gruß RENÈ